Support pour webcam

OpenSCAD

D'un aspect plutôt austère, cet outil de modélisation a une approche « script ». En résumé, la souris ne sert qu'à regarder la pièce sous différents angles.

La pièce sera composée d'un rectangle, et d'un demi-cercle dépassant de ce rectangle.

On commence par le rectangle (44 mm × 40 mm). Taper dans la zone de texte, dans l'éditeur :

square([44,40]);

Appuyer sur la touche F5. Un rectangle doit apparaître dans la zone de visualisation.

Maintenant, on ajoute un cercle, de diamètre 44 mm :

circle(d=44);

Un appui sur F5 et… ah, ben, c'est pas bon en fait.

Le cercle a été tracé en utilisant les coordonnées x = 0, y = 0, Z = 0 comme point central.

Il faut donc déplacer le centre de ce cercle, disons, de 22 mm sur l'axe des x (axe rouge indiqué dans le coin en bas à gauche, dans la visualisation).

On va utiliser l'instruction translate sur le cercle.

Modifier le code comme suit :

translate([22,0,0]) {
    circle(d=44);
};

Les deux éléments se superposent, ça serait bien de les fusionner réellement.

Modifier le code comme suit :

union() {
    square([44,40]);
    translate([22,0,0]) {
        circle(d=44);
    };
}

Maintenant, on va enlever de la matière (soustraire), via l'instruction difference.

Le cercle correspondant à la matière à retirer devra avoir son centre positionné au même endroit que le cercle initial ; donc déplacement sur l'axe des x de 22 mm.

On va prendre un peu de marge, et creuser avec un diamètre de 37mm. Il y aura un léger jeu dans la pièce, mais ce n'est pas trop grave ⁴.

difference() {

    //Pièce de base
    union() {
        square([44,40]);
        translate([22,0,0]) {
            circle(d=44);
        };
    }

    //cercle (matière à retirer)
    translate([22,0,0]) {
        circle(d=37);
    };
}

//ce commentaire tient sur une seule ligne

/*
 * Ce commentaire tient
 * sur plusieurs lignes.
 */

Admettons que l'on veuille juste tester l'instruction difference sur le cercle. On modifierait le code comme ceci :

difference() {

    //Pièce de base
//    union() {
//        square([44,40]);
        translate([22,0,0]) {
            circle(d=44);
        };
//    }

    //cercle (matière à retirer)
    translate([22,0,0]) {
        circle(d=37);
    };
}

C'était juste pour l'exemple.

Décommenter le code.

On va maintenant découper la fente. On ajoute une nouvelle différence dans l'ensemble, avec un rectangle de 37 mm × 13 mm, et centré par rapport au rectangle, mais décalé par rapport au cercle.

difference() {
    difference() {

        //Pièce de base
        union() {
            square([44,40]);
            translate([22,0,0]) {
                circle(d=44);
            };
        }

        //cercle (matière à retirer)
        translate([22,0,0]) {
            circle(d=37);
        };
    }
    //rectangle (matière à retirer)
    translate([3.5,22,0]) {
        square([37,13]);
    };
}

Maintenant, il faut donner du « volume » à la pièce. On va faire alors une extrusion linéaire, via linear_extrude, d'une hauteur de 50 mm.

linear_extrude(height=50) {
    difference() {
        difference() {

            //Pièce de base
            union() {
                square([44,40]);
                translate([22,0,0]) {
                    circle(d=44);
                };
            }

            //cercle (matière à retirer)
            translate([22,0,0]) {
                circle(d=37);
            };
        }
        //rectangle (matière à retirer)
        translate([3.5,22,0]) {
            square([37,13]);
        };
    }
}

On a presque fini avec la modélisation.

Pour éviter que ce support ne tombe, ça serait bien de boucher l'une des extrémités circulaire.

On va alors ajouter un cylindre dans la partie circulaire, d'une épaisseur de 5 mm.

union() {
    linear_extrude(height=50) {
        difference() {
            difference() {

                //Pièce de base
                union() {
                    square([44,40]);
                    translate([22,0,0]) {
                        circle(d=44);
                    };
                }

                //cercle (matière à retirer)
                translate([22,0,0]) {
                    circle(d=37);
                };
            }
            //rectangle (matière à retirer)
            translate([3.5,22,0]) {
                square([37,13]);
            };
        }
    }

    //cylindre servant de « bouchon »
    translate([22,0,0]) {
        cylinder(h=5, d=44);
    }
}

On a presque fini.

Appuyer sur F6 pour calculer le rendu (F5 ne fait qu'un aperçu).

Appuyer ensuite sur F7 pour générer un fichier .stl.

Le fichier .scad est disponible ici : support-logitech-streamcam.scad. ; tout comme le fichier .stl support-logitech-streamcam.stl.

La partie modélisation est terminée.

Préparation de l'impression 3D

Bien, maintenant que l'on a notre fichier stl, on va pouvoir l'imprimer ? En fait, non. Il y a une étape intermédiaire : transformer un modèle 3D en un fichier interprétable par l'imprimante, le fichier gcode⁵.

Prenez votre logiciel préféré ⁶, et importez le fichier .stl.

Faire les réglages habituels, je n'entrerai pas dans les détails, ça change d'une imprimante 3D à l'autre⁷.

Faire le découpage/trancher/slicer (le mot peut varier).

Ne pas hésiter à visualiser le résultat couche par couche.

Enfin, générez le G-Code, et l'envoyer à l'imprimante (via Octoprint, avec une microSD, etc).

Impression 3D

Patienter quelques heures, le temps que la machine imprime la pièce⁸.

Résultat

Résultat en images :

Et une fois en place :